TI-Basic: Programme und Tutorials: Quersumme und Querprodukt

Hoch zu "Programme und Tutorials"

Erstellt von:	Peter Riedel
Schwierigkeitsgrad:	fortgeschritten
Modell:	Voyage 200

Quersumme

 Quersumme

Bei folgenden Funktionen und Programmen ist es nicht nötig die Ziffernanzahl $k$ der natürlichen Zahl $n$ als zweites Argument zu übergeben, sondern wird intern mithilfe der Funktion $\operatorname {numdigit} (n,1)$ in Abhängigkeit von $n$ automatisch berechnet. $k$ wird im Quelltext also durch $\operatorname {numdigit} (n,1)$ ersetzt. Allerdings kann das häufige Aufrufen von Funktionen bei Zahlen mit vielen Stellen die Geschwindigkeit der Ausführung deutlich verringern. Daher sollte man bei rechenintensiven Anwendungen $k$ mitübergeben, auch wenn das weniger komfortabel ist als nur ein Argument übergeben zu müssen.

Linksassoziativ

$k$ Ziffern der natürlichen Zahl $n$ werden von links nach rechts ziffernweise addiert, sodass man die Quersumme $\operatorname {qs} (n,k)$ von $n$ erhält.

$\operatorname {qs} (n,k)=\sum _{i=0}^{k-1}\;{\frac {n\;\operatorname {mod} \;10^{k-i}\;-\;n\;\operatorname {mod} \;10^{k-i-1}}{10^{k-i-1}}}\;\Leftrightarrow \;\operatorname {qs} (n,k)=\sum _{i=1}^{k}\;{\frac {n\;\operatorname {mod} \;10^{k-i+1}\;-\;n\;\operatorname {mod} \;10^{k-i}}{10^{k-i}}}$

Funktion

:digitsum(n)
:Func
:If n<0 or mod(n,1)≠0
:  Return undef
:Return Σ((mod(n,10^(numdigit(n,1)-i))-mod(n,10^(numdigit(n,1)-1-i)))/10^(numdigit(n,1)-1-i),i,0,numdigit(n,1)-1)
:EndFunc

Programm

:digitsum(n)
:Prgm
:ClrIO
:If n<0 or mod(n,1)≠0 Then
:  Disp "Error: n ∈ N = {0,1,2,...,∞}"
:  Return
:EndIf
:numdigit(n,1)→i
:string(n)→n
:0→q
:0→k
:While k<i
:  k+1→k
:  expr(mid(n,k,1))→j
:  q+j→q
:EndWhile
:string(q)→q
:Disp "digit sum: "&q
:EndPrgm

Rechtsassoziativ

$k$ Ziffern der natürlichen Zahl $n$ werden von rechts nach links ziffernweise addiert, sodass man die Quersumme $\operatorname {qs} (n,k)$ von $n$ erhält.

$\operatorname {qs} (n,k)=\sum _{i=0}^{k-1}\;{\frac {n\;\operatorname {mod} \;10^{i+1}\;-\;n\;\operatorname {mod} \;10^{i}}{10^{i}}}\;\Leftrightarrow \;\operatorname {qs} (n,k)=\sum _{i=1}^{k}\;{\frac {n\;\operatorname {mod} \;10^{i}\;-\;n\;\operatorname {mod} \;10^{i-1}}{10^{i-1}}}$

Funktion

:digitsum(n)
:Func
:If n<0 or mod(n,1)≠0
:  Return undef
:Return Σ((mod(n,10^(i+1))-mod(n,10^i))/10^i,i,0,numdigit(n,1)-1)
:EndFunc

Programm

:digitsum(n)
:Prgm
:ClrIO
:If n<0 or mod(n,1)≠0 Then
:  Disp "Error: n ∈ N = {0,1,2,...,∞}"
:  Return
:EndIf
:numdigit(n,1)→i
:string(n)→n
:0→q
:While i>0
:  expr(mid(n,i,1))→j
:  q+j→q
:  i-1→i
:EndWhile
:string(q)→q
:Disp "digit sum: "&q
:EndPrgm

Iterative Quersumme

 Iterative Quersumme

Rekursion

$\operatorname {itqs} (n,k)={\begin{cases}\operatorname {qs} (n,k),&{\mbox{wenn }}0\leq \operatorname {qs} (n,k)<10\\\operatorname {itqs} (\operatorname {qs} (n,k),\operatorname {num(qs} (n,k),1)),&{\mbox{wenn }}10\leq \operatorname {qs} (n,k)<\infty \end{cases}}$

$\operatorname {num} (n,i)={\begin{cases}\operatorname {num} (n,i+1),&{\mbox{wenn }}n\operatorname {mod} 10^{i}<n\\i,&{\mbox{wenn }}n\operatorname {mod} 10^{i}=n\end{cases}}$

Funktion

:itqs(n)
:Func
:If qs(n)<10 Then
:  Return qs(n)
:Else
:  Return itqs(qs(n))
:EndIf
:EndFunc

Programm

:itqs(n)
:Prgm
:ClrIO
:If n<0 or mod(n,1)≠0 Then
:  Disp "Error: n ∈ N = {0,1,2,...,∞}"
:  Return
:EndIf
:0→k
:While n>9
:  num(n,1)→i
:  string(n)→n
:  0→q
:  While i>0
:    expr(mid(n,i,1))→j
:    q+j→q
:    i-1→i
:  EndWhile
:  k+1→k
:  q→n
:EndWhile
:string(n)→n
:string(k)→k
:Disp "additive digital root: "&n,"additive persistence: "&k
:EndPrgm